//============== Script =======================================
//= Custom Universal Renter (Payment)
//===== By: ==================================================
//= James ~ LotusRO ~ lotusragnarok.com
//===== Description: =========================================
//= A Peco Peco, Grand Peco Peco, Falcon, and Cart rental NPC
//= which requires you to pay to rent. Normal prices and
//= requirements from original NPCs.
//===== Additional Comments: =================================
//= Greatly modified from eAthena's Free Universal Rental NPC.
//============================================================

prontera.gat,181,215,4    script    Sheila    726,{
     mes "[Sheila]";
     mes "Hi, here you can rent Carts, Falcons or Pecopecos.";
     next;

L_Menu:
     menu "Rent a Cart",L_Cart,"Rent a Falcon",L_Falcon,"Rent a Pecopeco",L_Peco,"Quit",L_Quit;
     close;

//---------------------------------------CART CODE----------------------------------------

L_Cart:
     if(BaseClass != Job_Merchant && BaseJob != Job_SuperNovice ) {
         mes "[Sheila]";
         mes "You are not the right class to rent a cart!";
         close;
     }
     if(BaseClass == Job_Merchant) set @price,800; //Default Cart
     if(BaseJob == Job_SuperNovice) set @price,1900; //Super Novice Cart

     mes "[Sheila]";
     if(BaseClass == Job_Merchant)mes "I can rent you a Cart, but you need "+@price+"z and the ^5555FF'Pushcart'^000000 skill.";
     if(BaseJob == Job_SuperNovice)mes "I can rent you a Cart specialized for Super Novices, but you need "+@price+"z and the ^5555FF'Pushcart'^000000 skill.";
     next;
     menu "Ok",cM_0, "No thanks",cM_End;

     cM_0:
         if(getskilllv(39) == 0) goto cL_NeedSkill;
         if(Zeny < @price) goto cL_Zeny;
         if(checkcart() == 1) goto cL_GotCart;
         set Zeny, Zeny - @price;
         setcart;
         mes "Thank you and good day.";
         emotion 15;
         close;

         cL_NeedSkill:
             mes "[Sheila]";
             mes  "As I mentioned earlier, you need the ^3333FFPushcart^000000 skill in order to rent a Cart.";
             close;
         cL_Zeny:
             mes "[Sheila]";
             mes "As I said before it will be "+@price+"z. Come back when you have enough zeny.";
             close;
         cL_GotCart:
             mes "[Sheila]";
             mes "Umm... Don't you already have a Cart??....";
             emotion 20;
             close;
     cM_End:
         mes "[Sheila]";
         mes "Alright.  Good day to you.";
         close;

//--------------------------------------- FALCON CODE----------------------------------------

L_Falcon:
     if(BaseJob != Job_Hunter) {
         mes "[Sheila]";
         mes "You are not the right class to rent a Falcon!";
         close;
     }
     if(Upper==0) set @price,800; //Normal Falcon - default price
     if(Upper==1) set @price,1000; //Scarf Falcon
     if(Upper==2) set @price,600; //Baby Falcon

     mes "[Sheila]";
     if(Upper==0)mes "I can train a Falcon for you, but you need "+@price+"z and be a Hunter with mastered ^5555FF'Falcon Mastery'^000000 skill.";
     if(Upper==1)mes "I can train a Scarf Falcon for you, but you need "+@price+"z and be a Sniper with mastered ^5555FF'Falcon Mastery'^000000 skill.";
     if(Upper==2)mes "I can train a Baby Falcon for you, but you need "+@price+"z and be a Baby Hunter with mastered ^5555FF'Falcon Mastery'^000000 skill.";
     next;
     menu "Ok",sM_0, "No thanks",sM_End;

     sM_0:
         if(checkfalcon() != 0) goto sL_GotFalc;
         if(Zeny < @price) goto sL_Zeny;
         if(getskilllv(127)==0) goto sL_NoSkill;
         set Zeny, Zeny - @price;
         mes "[Sheila]";
         mes "It looks like you meet all the requirements to handle a Falcon.  Here you are";
         setfalcon;
         next;
         mes "[Sheila]";
         mes "Please take very good care of it.  It will prove to be a valuable companion.";
         close;
          
         sL_GotFalc:
             mes "[Sheila]";
             mes "You can only have 1 Falcon at a time.";
             close;
         sL_NoSkill:
             mes "[Sheila]";
             mes "I'm sorry but you do not have the Falcon Mastery skill.  Please come back when you have learned it.";
             close;
         sL_Zeny:
             mes "[Sheila]";
             mes "As I said before it will be "+@price+"z. Come back when you aquire enough zeny.";
             close;
     sM_End:
         mes "[Sheila]";
         mes "Have a nice day.";
         close;

//---------------------------------------PECOPECO CODE----------------------------------------

L_Peco:
     if(BaseJob != Job_Knight && BaseJob != Job_Knight2 && BaseJob != Job_Crusader && BaseJob != Job_Crusader2 ) {
         mes "[Sheila]";
         mes "You are not the right class to rent a PecoPeco!";
         close;
     }
     if(BaseJob == Job_Knight || BaseJob == Job_Knight2 ) {
         if(Upper==0) set @price,2500; //Normal Peco - default price
         if(Upper==1) set @price,4000; //Armored Peco
         if(Upper==2) set @price,2000; //Baby Peco
         goto L_Start_KLK;
     }
     if(BaseJob == Job_Crusader || BaseJob == Job_Crusader2 ) {
         if(Upper==0) set @price,3000; //Normal Peco - default price
         if(Upper==1) set @price,5000; //Armored Peco
         if(Upper==2) set @price,2500; //Baby Peco
         goto L_Start_CP;
     }

L_Start_KLK:
     mes "[Sheila]";
     mes "You can rent one PecoPeco for "+@price+" Zeny, provided that you have the PecoPeco Riding skill.";
     next;
     menu "Lend me a trusty steed!... err... bird!",pM_0,"Hmm...It's a bit too expensive.",pM_1;

     pM_0:
         if(getskilllv(63) == 0) goto pL_NeedSkill;
         if(Zeny < @price) goto pL_Zeny;
         if(checkriding() != 0) goto pL_GotPeco;
         set Zeny, Zeny - @price;
         setriding;
         mes "Thank you and good day.";
         emotion 15;
         close;

         pL_NeedSkill:
             mes "[Sheila]";
             mes  "As I mentioned earlier, you need the ^3333FFRiding^000000 skill in order to rent a PecoPeco.";
             close;
         pL_Zeny:
             mes "[Sheila]";
             mes "As I said before it will be "+@price+"z. Come back when you have enough zeny.";
             close;
         pL_GotPeco:
             mes "[Sheila]";
             mes "Umm... aren't you already riding a PecoPeco??....";
             emotion 20;
             close;
     pM_1:
         mes "[Sheila]";
         mes "Alright.  Good day to you.";
         close;

L_Start_CP:
     mes "[Sheila]";
     mes "You can rent one Grand PecoPeco for "+@price+" Zeny, provided that you have the PecoPeco Riding skill.";
     next;
     menu "Lend me a trusty steed!... err... bird!",pM_2,"Hmm...It's a bit too expensive.",pM_3;

     pM_2:
         if(getskilllv(63) == 0) goto pL_NeedSkill2;
         if(Zeny < @price) goto pL_Zeny2;
         if(checkriding() != 0) goto pL_GotPeco2;
         set Zeny, Zeny - @price;
         setriding;
         mes "Thank you and good day.";
         emotion 15;
         close;

         pL_NeedSkill2:
             mes "[Sheila]";
             mes  "As I mentioned earlier, you need the ^3333FFRiding^000000 skill in order to rent a Grand PecoPeco.";
             close;
         pL_Zeny2:
             mes "[Sheila]";
             mes "As I said before it will be "+@price+"z. Come back when you have enough zeny.";
             close;
         pL_GotPeco2:
             mes "[Sheila]";
             mes "Umm... aren't you already riding a Grand PecoPeco??....";
             emotion 20;
             close;
     pM_3:
         mes "[Sheila]";
         mes "Alright.  Good day to you.";
         close;

//---------------------------------------OTHER CODE----------------------------------------

L_Quit:
     mes "[Sheila]";
     mes strcharinfo(0) + ", please come back when you are ready to rent something.";
     close;
}